Step 3　インターネットエクスプローラを起動しホームページを開くテスト

Yahoo・Googleの検索順位チェックソフトを作ってみよう

Step 3　インターネットエクスプローラを起動しホームページを開くテスト

以前作成した、リンク切れチェックソフトのIEオープン部分を流用しテストします。

シート画面

「チェック開始」ボタンをクリックすると、Internet Explorerを起動し「Excel-Excel !」を開きます。
エクセル VBA

テストコード

下記のコードを入力してください。

Option Explicit

Private tIEobj As Object

Private Sub ExCreateIEobjectClose()
On Error Resume Next
    tIEobj.Quit
    Set tIEobj = Nothing
End Sub

Private Function ExCreateIEobject() As Boolean
    Dim sttime As Long
    Dim passtime As Long

    ExCreateIEobject = False
On Error GoTo ErrExit
    Set tIEobj = CreateObject("InternetExplorer.application")
    tIEobj.navigate "http://www.feedsoft.net/excel/"
    tIEobj.Visible = True
    '読み込みが終わるまで30秒待つ
    sttime = Timer
    Do
        '経過時間を算出
        passtime = Timer - sttime
        DoEvents
        If passtime >= 30 Then
            Exit Do
        End If
        '読込み完了
        If tIEobj.ReadyState = 4 Then
            Exit Do
        End If
    Loop
    If tIEobj.ReadyState <> 4 Then
        MsgBox "IEをオープンできませんでした。処理を中止します。"
    Else
        If LCase(tIEobj.Document.URL) <> LCase("http://www.feedsoft.net/excel/") Then
            MsgBox "入力されたURLを開くことができませんでした。URLを確認してください。"
        Else
            ExCreateIEobject = True
        End If
    End If
    Exit Function
ErrExit:
    MsgBox "処理中にエラーが発生しました。処理を中止します。" & vbCrLf & Err.Description
On Error Resume Next
    tIEobj.Quit
    Set tIEobj = Nothing
End Function

下記のコードに変更してください。

Private Sub CommandButton1_Click()
    If ExCreateIEobject Then
        MsgBox "ホームページがオープンしました。"
        ExCreateIEobjectClose
    End If
End Sub

Topへ